// SPDX-FileCopyrightText: 2023 - 2024 Open Mobile Platform LLC <community@omp.ru>

// SPDX-FileCopyrightText: 2013 Jolla Ltd

// SPDX-License-Identifier: BSD-3-Clause

import QtQuick 2.0

import QtQuick.Layouts 1.0

import QtFeedback 5.0
import Sailfish.Silica 1.0

Page {
    id: page

    property var effects: [ThemeEffect.Press, ThemeEffect.Release, ThemeEffect.PressWeak, ThemeEffect.ReleaseWeak, ThemeEffect.PressStrong, ThemeEffect.ReleaseStrong, ThemeEffect.DragStart, ThemeEffect.DragDropInZone, ThemeEffect.DragDropOutOfZone, ThemeEffect.DragCrossBoundary, ThemeEffect.Appear, ThemeEffect.Disappear, ThemeEffect.Move]

    property var effectsDescription: [
        //% "Press / Button"
        qsTrId("ui-component-gallery-haptic-press-button"),
        //% "Release"
        qsTrId("ui-component-gallery-haptic-release"),
        //% "PressWeak / Keypad"
        qsTrId("ui-component-gallery-haptic-press-weak-keypad"),
        //% "ReleaseWeak"
        qsTrId("ui-component-gallery-haptic-release-weak"),
        //% "PressStrong / Long"
        qsTrId("ui-component-gallery-haptic-press-strong-long"),
        //% "ReleaseStrong"
        qsTrId("ui-component-gallery-haptic-release-strong"),
        //% "DragStart"
        qsTrId("ui-component-gallery-haptic-drag-start"),
        //% "DragDropInZone"
        qsTrId("ui-component-gallery-haptic-drag-drop-in-zone"),
        //% "DragDropOutOfZone"
        qsTrId("ui-component-gallery-haptic-drag-drop-out-of-zone"),
        //% "DragCrossBoundary"
        qsTrId("ui-component-gallery-haptic-drag-cross-boundary"),
        //% "Appear"
        qsTrId("ui-component-gallery-haptic-appear"),
        //% "Disappear"
        qsTrId("ui-component-gallery-haptic-disappear"),
        //% "Move"
        qsTrId("ui-component-gallery-haptic-move")]

    ThemeEffect {

        id: customVibro

    }

    HapticsEffect {
        id: customBuzz
        intensity: intensitySlider.value
        duration: Math.round(durationSlider.value)
    }

    HapticsEffect {
        id: periodicBuzz
        intensity: 0.9
        duration: 2000
        attackTime: 500
        fadeTime: 1000
        attackIntensity: 0.5
        fadeIntensity: 0.1
        period: 20
    }

    SilicaFlickable {
        anchors.fill: parent
        contentHeight: column.height + Theme.paddingLarge
        contentWidth: parent.width

        VerticalScrollDecorator {
        }

        Column {
            id: column

            width: parent.width
            spacing: Theme.paddingLarge

            PageHeader {

                title: "Haptics"

            }

            SectionHeader {

                //% "Custom effects"
                text: qsTrId("ui-component-gallery-haptic-custom-effects")

            }
            Button {

                //% "Periodic"
                text: qsTrId("ui-component-gallery-haptic-periodic")

                anchors.horizontalCenter: parent.horizontalCenter
                onPressed: periodicBuzz.start()
            }
            Label {
                x: Theme.horizontalPageMargin

                //% "Effect duration:"
                text: qsTrId("ui-component-gallery-haptic-effect-duration")

            }
            Slider {
                id: durationSlider
                width: page.width
                value: 20
                valueText: Math.round(durationSlider.value)
                minimumValue: 1
                maximumValue: 500
            }
            Label {
                x: Theme.horizontalPageMargin

                //% "Effect intensity:"
                text: qsTrId("ui-component-gallery-haptic-effect-intensity")

            }
            Slider {
                id: intensitySlider
                width: page.width
                value: 0.5
                valueText: Math.round(intensitySlider.value)
                minimumValue: 0.1
                maximumValue: 1.0
            }
            Button {

                //% "onPressed"
                text: qsTrId("ui-component-gallery-haptic-on-pressed")

                anchors.horizontalCenter: parent.horizontalCenter
                onPressed: customBuzz.start()
            }
            Button {
                anchors.horizontalCenter: parent.horizontalCenter

                //% "onReleased"
                text: qsTrId("ui-component-gallery-haptic-on-released")

                onReleased: customBuzz.start()
            }
            Button {

                //% "onClicked"
                text: qsTrId("ui-component-gallery-haptic-on-clicked")

                anchors.horizontalCenter: parent.horizontalCenter
                onClicked: customBuzz.start()
            }
            Button {

                //% "onPressed, onReleased"
                text: qsTrId("ui-component-gallery-haptic-on-pressed-on-released")

                anchors.horizontalCenter: parent.horizontalCenter
                onPressed: customBuzz.start()
                onReleased: customBuzz.start()
            }

            SectionHeader {
                //% "onPressed effects (Qt name / Theme name)"
                text: qsTrId("ui-component-gallery-haptic-on-pressed-effects-qt-name-theme-name")
            }
            GridLayout {
                anchors.horizontalCenter: parent.horizontalCenter
                width: page.width - Theme.paddingMedium * 2
                columns: 2
                rowSpacing: Theme.paddingLarge

                Repeater {
                    model: effects

                    Button {
                        preferredWidth: Theme.buttonWidthExtraSmall
                        text: effectsDescription[index]
                        onPressed: customVibro.play(effects[index])
                    }
                }
            }

        }
    }
}