// SPDX-FileCopyrightText: 2023 Open Mobile Platform LLC <community@omp.ru>

// SPDX-FileCopyrightText: 2013 Jolla Ltd

// SPDX-License-Identifier: BSD-3-Clause

import QtQuick 2.0
import QtFeedback 5.0
import Sailfish.Silica 1.0

Page {
    id: page

    ThemeEffect {
        id: buttonBuzz
        effect: ThemeEffect.Press
    }

    ThemeEffect {
        id: keypadBuzz
        effect: ThemeEffect.PressWeak
    }

    ThemeEffect {
        id: longBuzz
        effect: ThemeEffect.PressStrong
    }

    HapticsEffect {
        id: customBuzz
        intensity: intensitySlider.value
        duration: Math.round(durationSlider.value)
    }

    HapticsEffect {
        id: periodicBuzz
        intensity: 0.9
        duration: 2000
        attackTime: 500
        fadeTime: 1000
        attackIntensity: 0.5
        fadeIntensity: 0.1
        period: 20
    }

    SilicaFlickable {
        anchors.fill: parent
        contentHeight: column.height + Theme.paddingLarge
        contentWidth: parent.width

        VerticalScrollDecorator {
        }

        Column {
            id: column

            width: parent.width
            spacing: Theme.paddingLarge

            PageHeader {

                //% "Haptics"
                title: qsTrId("ui-component-gallery-haptic-haptics")

            }

            SectionHeader {

                //% "Theme effects, onPressed"
                text: qsTrId("ui-component-gallery-haptic-theme-effects-on-pressed")

            }
            Button {

                //% "Long"
                text: qsTrId("ui-component-gallery-haptic-long")

                anchors.horizontalCenter: parent.horizontalCenter
                onPressed: longBuzz.play()
            }
            Button {

                //% "Button"
                text: qsTrId("ui-component-gallery-haptic-button")

                anchors.horizontalCenter: parent.horizontalCenter
                onPressed: buttonBuzz.play()
            }
            Button {

                //% "Keypad"
                text: qsTrId("ui-component-gallery-haptic-keypad")

                anchors.horizontalCenter: parent.horizontalCenter
                onPressed: keypadBuzz.play()
            }
            Button {

                //% "Periodic"
                text: qsTrId("ui-component-gallery-haptic-periodic")

                anchors.horizontalCenter: parent.horizontalCenter
                onPressed: periodicBuzz.start()
            }
            SectionHeader {

                //% "Custom effects"
                text: qsTrId("ui-component-gallery-haptic-custom-effects")

            }
            Label {
                x: Theme.horizontalPageMargin

                //% "Effect duration:"
                text: qsTrId("ui-component-gallery-haptic-effect-duration")

            }
            Slider {
                id: durationSlider
                width: page.width
                value: 20
                valueText: Math.round(durationSlider.value)
                minimumValue: 1
                maximumValue: 500
            }
            Label {
                x: Theme.horizontalPageMargin

                //% "Effect intensity:"
                text: qsTrId("ui-component-gallery-haptic-effect-intensity")

            }
            Slider {
                id: intensitySlider
                width: page.width
                value: 0.5
                valueText: Math.round(intensitySlider.value)
                minimumValue: 0.1
                maximumValue: 1.0
            }
            Button {

                //% "onPressed"
                text: qsTrId("ui-component-gallery-haptic-on-pressed")

                anchors.horizontalCenter: parent.horizontalCenter
                onPressed: customBuzz.start()
            }
            Button {
                anchors.horizontalCenter: parent.horizontalCenter

                //% "onReleased"
                text: qsTrId("ui-component-gallery-haptic-on-released")

                onReleased: customBuzz.start()
            }
            Button {

                //% "onClicked"
                text: qsTrId("ui-component-gallery-haptic-on-clicked")

                anchors.horizontalCenter: parent.horizontalCenter
                onClicked: customBuzz.start()
            }
            Button {

                //% "onPressed, onReleased"
                text: qsTrId("ui-component-gallery-haptic-on-pressed-on-released")

                anchors.horizontalCenter: parent.horizontalCenter
                onPressed: customBuzz.start()
                onReleased: customBuzz.start()
            }
        }
    }
}