// SPDX-FileCopyrightText: 2020 Open Mobile Platform LLC <community@omp.ru>

// SPDX-License-Identifier: BSD-3-Clause

import QtQuick 2.0
import Sailfish.Silica 1.0

Column {
    id: root

    property alias model: repeater.model
    property bool exclusive: true
    property string selectedRole: "selected"
    property string valueRole: "value"
    property string nameRole: "name"
    property string iconRole: "icon"
    property string descriptionRole: "description"

    signal selectedValuesChanged

    function selectedValues() {
        var selectedValues = new Array(children.length - 1);
        if (exclusive) {
            if (repeater.selectedIndex >= 0)
                selectedValues[repeater.selectedIndex] = children[repeater.selectedIndex].value;
        } else {
            for (var iChild = 0; iChild < selectedValues.length; ++iChild) {
                var child = children[iChild];
                if (child.checked)
                    selectedValues[iChild] = child.value;
            }
        }
        return selectedValues;
    }

    width: parent ? parent.width : Screen.width

    Repeater {
        id: repeater

        property int selectedIndex: -1

        onModelChanged: selectedIndex = -1
        delegate: switchDelegate
    }

    Component {
        id: switchDelegate

        IconTextSwitch {
            id: switchItem

            readonly property var m: model.modelData || model
            readonly property var value: m[root.valueRole] === undefined ? m : m[root.valueRole]

            onClicked: {
                if (checked) {
                    if (root.exclusive)
                        return;
                    checked = false;
                    repeater.selectedIndex = -1;
                } else {
                    checked = true;
                    repeater.selectedIndex = model.index;
                }
                root.selectedValuesChanged();
            }
            Component.onCompleted: {
                if (m[root.selectedRole])
                    repeater.selectedIndex = model.index;
            }

            text: m[root.nameRole] === undefined ? value : m[root.nameRole]
            description: m[root.descriptionRole] || ""
            icon.source: m[root.iconRole] || ""
            automaticCheck: false

            Binding {
                id: targetStateWatcher

                when: root.exclusive
                target: switchItem
                property: "checked"
                value: model.index === repeater.selectedIndex
            }
        }
    }
}