# SPDX-FileCopyrightText: 2023 Open Mobile Platform LLC <community@omp.ru>
# SPDX-License-Identifier: BSD-3-Clause
cmake_minimum_required(VERSION 3.5)

project(ru.auroraos.NeuralNetworksUseCases CXX)

find_package (
    Qt5
    COMPONENTS Core Network Qml Gui Quick LinguistTools
    REQUIRED)

include(FindPkgConfig)
pkg_search_module(AURORA auroraapp REQUIRED)

set(CMAKE_AUTOMOC ON)
set(CMAKE_INCLUDE_CURRENT_DIR ON)

set(CMAKE_SKIP_RPATH FALSE)
set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}/lib")

set(short_name NeuralNetworksUseCases)

file(GLOB TsFiles "translations/*.ts")

file(GLOB_RECURSE QmlFiles "qml/*.qml")

qt5_add_translation(QmFiles ${TsFiles})

set(SOURCES
    src/abstractneuralnetwork.cpp
    src/detectedobject.cpp
    src/helpers.cpp
    src/main.cpp
    src/nanodetexample.cpp
    src/ncnninstance.cpp
    src/ncnncreator.cpp
    src/opencvimageview.cpp
    src/yollov3example.cpp
    src/yollov7example.cpp
)

set(HEADERS
    src/abstractneuralnetwork.h
    src/detectedobject.h
    src/helpers.h
    src/nanodetexample.h
    src/ncnninstance.h
    src/ncnncreator.h
    src/opencvimageview.h
    src/yollov3example.h
    src/yollov7example.h
)

add_executable(${PROJECT_NAME}
    ${SOURCES}
    ${HEADERS}
    ${QmFiles}
    ${PROJECT_NAME}.desktop
    ${QmlFiles}
    ${TsFiles}
)

add_dependencies(${PROJECT_NAME}
    ncnn
    opencv_core
    opencv_imgcodecs
    opencv_imgproc
)

target_include_directories(${PROJECT_NAME} PUBLIC
     ${CMAKE_SOURCE_DIR}/opencv/opencv/modules/core/include
     ${CMAKE_SOURCE_DIR}/opencv/opencv/modules/imgcodecs/include
     ${CMAKE_SOURCE_DIR}/opencv/opencv/modules/imgproc/include
     ${CMAKE_SOURCE_DIR}/opencv/opencv/include
     ${CMAKE_BINARY_DIR}/
     ${CMAKE_SOURCE_DIR}/ncnn/ncnn/src
     ${CMAKE_BINARY_DIR}/ncnn/ncnn/src
)

target_compile_definitions(${PROJECT_NAME} PRIVATE
    $<$<OR:$<CONFIG:Debug>,$<CONFIG:RelWithDebInfo>>:QT_QML_DEBUG>
)

target_include_directories(${PROJECT_NAME} PRIVATE
    $<BUILD_INTERFACE:
    ${AURORA_INCLUDE_DIRS}
    >
)

target_link_directories(
    ${PROJECT_NAME}
    PRIVATE
    ${CMAKE_BINARY_DIR}/opencv/opencv/lib
    ${CMAKE_BINARY_DIR}/ncnn/ncnn/src
)

target_link_libraries(${PROJECT_NAME} PRIVATE
    Qt5::Quick
    ${AURORA_LDFLAGS}
    opencv_core
    opencv_imgcodecs
    opencv_imgproc
    ncnn
)

install(DIRECTORY ${CMAKE_SOURCE_DIR}/network
    DESTINATION share/common/ru.auroraos/${short_name}
)

install(TARGETS ${PROJECT_NAME}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

install(DIRECTORY qml
    DESTINATION share/${PROJECT_NAME}
)

foreach(_file IN LISTS QmFiles)
    get_filename_component(_filename "${_file}" NAME)
    string(REPLACE "${short_name}" "${PROJECT_NAME}" _full_filename "${_filename}")
    install(FILES ${_file} DESTINATION share/${PROJECT_NAME}/translations RENAME ${_full_filename})
endforeach()

set(IconSize 86x86 108x108 128x128 172x172)
foreach(_size IN LISTS IconSize)
    install(FILES icons/${_size}/${PROJECT_NAME}.png DESTINATION share/icons/hicolor/${_size}/apps)
endforeach()

install(FILES ${PROJECT_NAME}.desktop
    DESTINATION share/applications
)

file(WRITE "${CMAKE_BINARY_DIR}/QtCreatorDeployment.txt"
    "${CMAKE_INSTALL_PREFIX}
${CMAKE_BINARY_DIR}/${PROJECT_NAME}:bin
")
