# SPDX-FileCopyrightText: 2024 Open Mobile Platform LLC <community@omp.ru>
# SPDX-License-Identifier: BSD-3-Clause

cmake_minimum_required(VERSION 3.5)
project(ru.auroraos.Cryptographic CXX)

find_package (Qt5 COMPONENTS Core Network Qml Gui Quick LinguistTools REQUIRED)

include(FindPkgConfig)
pkg_search_module(AURORA auroraapp REQUIRED)
pkg_search_module(AURORA auroraapp_i18n REQUIRED)

find_package(PkgConfig REQUIRED)
pkg_check_modules(Qca2Qt5 qca2-qt5 IMPORTED_TARGET)

set(CMAKE_AUTOMOC ON)
set(CMAKE_INCLUDE_CURRENT_DIR ON)


set(short_name Cryptographic)

file(GLOB TsFiles "translations/*.ts")
qt5_create_translation(QmFiles ${CMAKE_SOURCE_DIR} ${TsFiles})

set(SOURCES
    resources.qrc
    src/main.cpp
    src/common/errorenum.h
    src/string-coding/coder.h
    src/string-coding/coder.cpp
    src/string-coding/encoder.h
    src/string-coding/encoder.cpp
    src/string-coding/decoder.h
    src/string-coding/decoder.cpp
    src/string-coding/encodedecodepagecontroller.h
    src/string-coding/encodedecodepagecontroller.cpp
    src/string-coding/codingenum.h
    src/string-encrypt/encryptpagecontroller.h
    src/string-encrypt/encryptpagecontroller.cpp
    src/string-encrypt/encryptenum.h
    src/string-encrypt/encryptenum.cpp
    src/md5crypt/md5cryptpagecontroller.h
    src/md5crypt/md5cryptpagecontroller.cpp
    src/string-hash/hashpagecontroller.h
    src/string-hash/hashpagecontroller.cpp
    src/string-hash/hashenum.h
    src/string-hash/hashenum.cpp
    src/mac/macpagecontroller.h
    src/mac/macpagecontroller.cpp
    src/mac/macenum.h
    src/mac/macenum.cpp
    src/random/randompagecontroller.h
    src/random/randompagecontroller.cpp
    src/random/randomenum.h
    src/all-cryptos/allcryptospagecontroller.h
    src/all-cryptos/allcryptospagecontroller.cpp
    src/all-cryptos/allcryptoslistmodel.h
    src/all-cryptos/allcryptoslistmodel.cpp
    src/all-cryptos/cryptoline.h
    src/all-cryptos/cryptoline.cpp
    src/request-handler/requesthandlerpagecontroller.h
    src/request-handler/requesthandlerpagecontroller.cpp
    src/request-handler/askerthread.h
    src/request-handler/askerthread.cpp
    src/request-handler/eventhandler.h
    src/request-handler/eventhandler.cpp
    src/certX509/certx509pagecontroller.h
    src/certX509/certx509pagecontroller.cpp
    src/certX509/certinfo.h
    src/certX509/certinfo.cpp
    src/certX509/certslistmodel.h
    src/certX509/certslistmodel.cpp
    src/certX509/certreadenum.h
    src/publickey/publickeypagecontroller.h
    src/publickey/publickeypagecontroller.cpp
    src/own-cryptoprovider/aescmaccontext.h
    src/own-cryptoprovider/aescmaccontext.cpp
    src/own-cryptoprovider/cryptoprovider.h
    src/own-cryptoprovider/cryptoprovider.cpp
    src/own-cryptoprovider/owncryptoproviderpagecontroller.h
    src/own-cryptoprovider/owncryptoproviderpagecontroller.cpp
    src/private-key-uploading/privatekeyuploadingpagecontroller.h
    src/private-key-uploading/privatekeyuploadingpagecontroller.cpp
)

qt5_add_resources(SOURCES resources.qrc)

set(CMAKE_SKIP_RPATH FALSE)
set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/share/${PROJECT_NAME}/lib")

add_executable(${PROJECT_NAME} ${SOURCES} ${QmFiles})
target_compile_definitions(${PROJECT_NAME} PRIVATE
    $<$<OR:$<CONFIG:Debug>,$<CONFIG:RelWithDebInfo>>:QT_QML_DEBUG>
)
target_include_directories(${PROJECT_NAME} PRIVATE
    $<BUILD_INTERFACE:
    ${AURORA_INCLUDE_DIRS}
>)
target_link_libraries(${PROJECT_NAME} PRIVATE
    Qt5::Quick
    PkgConfig::Qca2Qt5
    ${AURORA_LDFLAGS}
)

install(TARGETS ${PROJECT_NAME}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)
install(DIRECTORY qml
    DESTINATION share/${PROJECT_NAME}
)

foreach(_file IN LISTS QmFiles)
    get_filename_component(_filename "${_file}" NAME)
    string(REPLACE "${short_name}" "${PROJECT_NAME}" _full_filename "${_filename}")
    install(FILES ${_file} DESTINATION share/${PROJECT_NAME}/translations RENAME ${_full_filename})
endforeach()

set(IconSize 86x86 108x108 128x128 172x172)
foreach(_size IN LISTS IconSize)
    install(FILES icons/${_size}/${PROJECT_NAME}.png DESTINATION share/icons/hicolor/${_size}/apps)
endforeach()

install(FILES ${PROJECT_NAME}.desktop
    DESTINATION share/applications
)

# Get the other files reachable from the project tree in Qt Creator
file(GLOB_RECURSE IconFiles "icons" "*.png")
set(RESOURCE_FILES ${IconFiles})

file(GLOB_RECURSE QmlFiles "qml/*.qml")

add_custom_target(distfiles
    SOURCES
        ${PROJECT_NAME}.desktop
        rpm/${PROJECT_NAME}.spec
        ${QmlFiles}
        ${TsFiles}
        ${IconFiles})

file(WRITE "${CMAKE_BINARY_DIR}/QtCreatorDeployment.txt"
    "${CMAKE_INSTALL_PREFIX}
${CMAKE_BINARY_DIR}/${PROJECT_NAME}:bin
")
